Hspice TUTORIAL


2D Field Solver using HSPICE


We will present here a methodology to compute the Impedance of a Microstrip Transmission line using HSPICE 2D field solver. We show below the computation using the formula method. It gives 57 Ohms impedance for a 5 mils trace width and 4 mils separation from ground. We have assumed Er to be 4.3



Figure Impedance Calculation using Online Calculator

Let us try to do our calculation using HSPICE. Here is the HSPICE code of that will give you capacitance per unit length and inductance per unit length of a microstrip transmission line.

* W element, field-solver interface

*                  XXXXXX     
*  ------------------------------------ Z = 5mils
*       Er = 4.3   H = 4mils
*  ------------------------------------ Z = 1mils
*  //// Bottom Ground Plane ///////////
*  ------------------------------------ Z = 0

W1 in1   0 out1   0 FSmodel=demo N=1 l=0.97

* Materials
.MATERIAL copper METAL CONDUCTIVITY=5.76e+07
.MATERIAL diel_1 DIELECTRIC ER = 4.3  LOSSTANGENT=1.2e-3 CONDUCTIVITY=8.2e-4

* Conductor crossection shapes
.SHAPE rect RECTANGLE WIDTH = 5mils HEIGHT = 1mils

* Dielectric stack-up
.LAYERSTACK Stack 
+ LAYER = (copper, 1mils) 
+ LAYER = (diel_1 4mils) 

* Field-solver options
.FSOPTIONS myOption ACCURACY = LOW GRIDFACTOR = 1 
+ ComputeRo=yes ComputeRs=yes ComputeGo=Yes ComputeGd=yes PRINTDATA=YES

.MODEL demo W ModelType=FieldSolver 
+ LAYERSTACK=Stack FSOptions=myOption
+ RLGCFILE= rlgc.txt
+ CONDUCTOR = ( MATERIAL=copper, SHAPE=rect, ORIGIN=(1000mils, 5mils) )

*Analysis
.tran 0.1ns 100ns
.option post
.end




If you run this file in hspice, it will generate and rlgc file. The content of the rlgc file will look as follows.


*SYSTEM_NAME : demo
*
*       Half Space, AIR
*  ------------------------------------ Z = 1.270000e-004
*       diel_1   H = 1.016000e-004
*  ------------------------------------ Z = 2.540000e-005
*  //// Bottom Ground Plane ///////////
*  ------------------------------------ Z = 0

* L(H/m), C(F/m), Ro(Ohm/m), Go(S/m), Rs(Ohm/(m*sqrt(Hz)), Gd(S/(m*Hz))

.MODEL demo W MODELTYPE=RLGC, N=1
+ Lo = 3.447940e-007
+ Co = 9.477066e-011
+ Ro = 5.381888e+000
+ Go = 1.656011e-003
+ Rs = 2.132704e-003
+ Gd = 3.572770e-013


In the above rlgc file Lo denotes the inductance per meter, Co denotes the capacitance per meter and Ro denotes resistance per meter. Ignore Go, Rs and Gd for now.

From this we can calculate the characteristic impedance as follows

Zo = [L/C]1/2
= [3.447940e-007 / 9.477066e-011]1/2
= 60.31


The formula method calculates slightly less pedance. This represents 5.48 % of the actual value.

In the next page we will learn about the hspice code used for 2D field solvers.